GRAPHREP sizing:asymmetrical
PEN w:0.02cm

AVAL set-default:"Detailed" m:"Presentation"
AVAL set-default:"yes" resizeable:"Resizeable"
AVAL e:"Extended properties"
AVAL name:"Name"
AVAL set-default:"$ffffff" c:"Color"
AVAL fc:"Font color"
AVAL operation:"Operations"
AVAL opt:"Operation table"
AVAL att:"Attribute table"

AVAL isAct:"IsActive"
AVAL isAbstract:"IsAbstract"
AVAL ref_class:"Referenced class"
AVAL set-default:"5" wid:"Width"
SET width:(CM (wid))
AVAL set-default:"no" int:"With internal structure"
AVAL b:"User defined properties"

FILL color:(rgbval (c))
FONT color:(fc)

IF (resizeable ="yes" OR m="Conceptual")
  TABLE x:-2.5cm y:-1.8cm w:5cm h:3.6cm
    cols:3 w1:0.1cm w2:100% w3:0.1cm
    rows:3 h1:1cm h2:50% h3:50%
 
  STRETCH off

  IF (int = "no")

    IF (m = "Conceptual")
      RECTANGLE x:(tabx0) y:(taby0) w:(tabx3 - tabx0) h:(taby3 - taby0)
      FONT "Arial" bold color:(fc)
      IF (isAbstract = "yes")
        FONT italic bold color:(fc)
      ENDIF
      IF (ref_class = "")
        ATTR "Name" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby0 + (taby3 - taby0)/2) w:c:(tabw2) h:c:(tabh1+tabh2+tabh3)
      ELSE
        ATTR "Referenced class" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby0 + (taby3 - taby0)/2) w:c:(tabw2) h:c:(tabh1+tabh2+tabh3) format:"%o"
      ENDIF
      FONT
      IF (isAct = "yes")
        LINE x1:(tabx0+0.2cm) y1:(taby0) x2:(tabx0+0.2cm) y2:(taby3)
        LINE x1:(tabx3-0.2cm) y1:(taby0) x2:(tabx3-0.2cm) y2:(taby3)
      ENDIF
    
    ELSIF (m = "Detailed")
    
      RECTANGLE x:(tabx0) y:(taby0) w:(tabx3 - tabx0) h:(tabh1)
      FONT "Arial" bold color:(fc)
      IF (isAbstract = "yes")
        FONT italic bold color:(fc)
      ENDIF
      IF (ref_class = "")
        ATTR "Name" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby1) w:c:(tabx3 - tabx1) h:b:(taby1 - taby0)
      ELSE
        ATTR "Referenced class" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby1) w:c:(tabx3 - tabx1) h:b:(taby1 - taby0) format:"%o"
      ENDIF
      FONT "Arial" color:(fc)
      SET txt:""      
      IF (search(e, "«metaclass»", 0) >= 0) SET txt:(txt+"«metaclass» ") ENDIF
      IF (search(e, "«interface»", 0) >= 0) SET txt:(txt+"«interface» ") ENDIF
      IF (search(e, "«type»", 0) >= 0) SET txt:(txt+"«type» ") ENDIF
      IF (search(e, "«implementation class»", 0) >= 0) SET txt:(txt+"«implementation class» ") ENDIF
      IF (search(e, "«auxiliary»", 0) >= 0) SET txt:(txt+"«auxiliary» ") ENDIF
      IF (search(e, "«focus»", 0) >= 0) SET txt:(txt+"«focus» ") ENDIF
      IF (search(e, "«utility»", 0) >= 0) SET txt:(txt+"«utility» ") ENDIF
      IF (search(e, "«activity»", 0) >= 0) SET txt:(txt+"«activity» ") ENDIF
      IF (search(e, "«statemachine»", 0) >= 0) SET txt:(txt+"«statemachine» ") ENDIF
      IF (search(e, "«interaction»", 0) >= 0) SET txt:(txt+"«interaction» ") ENDIF
      SET txt:(txt+b)
      FONT "Arial" h:10pt color:(fc)
      IF (txt != "")
        TEXT (copy(txt,0,LEN txt)) x:(tabx1 + (tabx2 - tabx1)/2 + 0.2cm) y:(taby0 + 0.0cm) w:c:(tabw2) h:t:0.1cm line-break:rigorous
      ENDIF

      RECTANGLE x:(tabx0) y:(taby1) w:(tabx3 - tabx0) h:(taby2 - taby1)
      IF (att != "")
        ATTR "Attribute table" x:(tabx1) y:(taby1) w:(tabx2 - tabx1) h:(taby2 - taby1)
      ENDIF
      
      RECTANGLE x:(tabx0) y:(taby2) w:(tabx3 - tabx0) h:(taby3 - taby2)
      IF (opt != "")
        ATTR "Operation table" x:(tabx1) y:(taby2) w:(tabx2 - tabx1) h:(taby3 - taby2)
      ENDIF
      
    ELSE
      
      RECTANGLE x:(tabx0) y:(taby0) w:(tabx3 - tabx0) h:(taby1 - taby0)
      FONT "Arial" bold color:(fc)
      IF (isAbstract = "yes")
        FONT italic bold color:(fc)
      ENDIF
      IF (ref_class = "")
        ATTR "Name" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby1) w:c:(tabx3 - tabx1) h:b:(taby1 - taby0)
      ELSE
        ATTR "Referenced class" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby1) w:c:(tabx3 - tabx1) h:b:(taby1 - taby0) format:"%o"
      ENDIF
      FONT "Arial" color:(fc)

      RECTANGLE x:(tabx0) y:(taby1) w:(tabx3 - tabx0) h:(taby2 - taby1)
      IF (att != "")
        ATTR "Attribute table" x:(tabx1) y:(taby1) w:(tabx2 - tabx1) h:(taby2 - taby1)
      ENDIF
      RECTANGLE x:(tabx0) y:(taby2) w:(tabx3 - tabx0) h:(taby3 - taby2)
      IF (opt != "")
        ATTR "Operation table" x:(tabx1) y:(taby2) w:(tabx2 - tabx1) h:(taby3 - taby2)
      ENDIF
    ENDIF

    AVAL t:"Template"
    IF (t = "yes")
      PEN style:dot
      FILL color:white
      RECTANGLE x:(tabx2 - 0.6cm) y:(taby0 - 0.1cm) w:(tabx3 - tabx2 + 0.7cm) h:(taby1 - taby0)
      FONT "Arial" h:10pt color:(fc)
      ATTR "Template parameter" x:(tabx2 - 0.2cm) y:(taby0 + (taby1 - taby0)/2) w:c:0.8cm h:c:1.0cm line-break:rigorous
    ENDIF

    AVAL s:"Details"
    IF (NOT (s = ""))
      FONT color:lightgray h:8pt color:(fc)
      ATTR "Details" x:c y:(taby3) format:"» %m" w:c:(tabw2)
    ENDIF

  ELSE
    RECTANGLE x:(tabx0) y:(taby0) w:(tabx3 - tabx0) h:(taby1 - taby0)
    RECTANGLE x:(tabx0) y:(taby1) w:(tabx3 - tabx0) h:(taby3 - taby1)
    IF (isAbstract = "yes")
      FONT italic bold color:(fc)
    ELSE
      FONT bold color:(fc)
    ENDIF

    IF (ref_class = "")
      ATTR "Name" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby1) w:c:(tabx3 - tabx1) h:b:(taby1 - taby0)
    ELSE
      ATTR "Referenced class" line-break:rigorous x:(tabx1 + (tabx2 - tabx1)/2) y:(taby1) w:c:(tabx3 - tabx1) h:b:(taby1 - taby0) format:"%o"
    ENDIF
    FONT
  ENDIF

ELSE

  FONT "Arial" bold color:(fc)
  IF (isAbstract = "yes")
    FONT italic bold color:(fc)
  ENDIF
  SHADOW on
  STRETCH off

  IF (ref_class = "")

    ATTRBOX "Name" x:((width/2) * -1 + 0.1cm) y:-0.5cm w:(width - 0.2cm) h:1.0cm
    RECTANGLE x:((width/2) * -1) y:-0.5cm w:(width) h:1.0cm
    ATTR "Name" x:0.0cm y:0.0cm w:c:(width - 0.2cm) h:1.0cm

  ELSE

    ATTRBOX "Referenced class" x:((width/2) * -1 + 0.1cm) y:-0.5cm w:(width - 0.2cm) h:1.0cm
    RECTANGLE x:((width/2) * -1) y:-0.5cm w:(width) h:1.0cm
    ATTR "Referenced class" x:0.0cm y:0.0cm w:c:(width - 0.2cm) h:1.0cm format:"%o"

  ENDIF
  FONT "Arial" color:(fc)
 
  IF (m = "Detailed")
    
    SET txt:""      
    IF (search(e, "«metaclass»", 0) >= 0) SET txt:(txt+"«metaclass» ") ENDIF
    IF (search(e, "«interface»", 0) >= 0) SET txt:(txt+"«interface» ") ENDIF
    IF (search(e, "«type»", 0) >= 0) SET txt:(txt+"«type» ") ENDIF
    IF (search(e, "«implementation class»", 0) >= 0) SET txt:(txt+"«implementation class» ") ENDIF
    IF (search(e, "«auxiliary»", 0) >= 0) SET txt:(txt+"«auxiliary» ") ENDIF
    IF (search(e, "«focus»", 0) >= 0) SET txt:(txt+"«focus» ") ENDIF
    IF (search(e, "«utility»", 0) >= 0) SET txt:(txt+"«utility» ") ENDIF
    IF (search(e, "«activity»", 0) >= 0) SET txt:(txt+"«activity» ") ENDIF
    IF (search(e, "«statemachine»", 0) >= 0) SET txt:(txt+"«statemachine» ") ENDIF
    IF (search(e, "«interaction»", 0) >= 0) SET txt:(txt+"«interaction» ") ENDIF
    SET txt:(txt+b)
    FONT "Arial" h:10pt color:(fc)
    IF (txt != "")
      TEXT (copy(txt,0,LEN txt)) x:0.0cm y:-0.5cm w:c:(width - 0.2cm) h:t:0.1cm line-break:rigorous
    ENDIF
 
  ENDIF

  AVAL t:"Template"
  IF (t = "yes")
    PEN style:dot
    FILL color:white
    
    RECTANGLE x:(width/2 - 0.7cm) y:-0.6cm w:0.8cm h:1cm
    FONT "Arial" h:10pt color:(fc)
    ATTR "Template parameter" x:(width/2 - 0.3cm) y:-0.1cm w:c:0.8cm h:c:1cm line-break:rigorous
  ENDIF

  PEN style:solid

  IF (NOT (att = ""))
    ATTRBOX "Attribute table" line-break:rigorous x:((width/2) * -1 + 0.1cm) y:0.5cm w:(width - 0.2cm)
    RECTANGLE x:((width/2) * -1) y:0.5cm w:(width) h:(texth)
    ATTR "Attribute table" line-break:rigorous x:((width/2) * -1 + 0.1cm) y:0.5cm w:(width - 0.2cm)
  ENDIF

  IF (NOT (opt = ""))
    ATTRBOX "Operation table" line-break:rigorous x:((width/2) * -1 + 0.1cm) y:(texty2) w:(width - 0.2cm)
    RECTANGLE x:((width/2) * -1) y:(texty1) w:(width) h:(texth)
    ATTR "Operation table" line-break:rigorous x:((width/2) * -1 + 0.1cm) y:(texty1) w:(width - 0.2cm)
  ENDIF

  AVAL s:"Details"
  IF (NOT (s = ""))
    FONT color:lightgray h:8pt
    ATTR "Details" x:c y:(texty2) format:"» %m" w:c:(width)
  ENDIF

  STRETCH on
ENDIF