GRAPHREP

#--------------- Define and Call Parameters--------------
AVAL s_Mode:"CommentMode"



AVAL n_MAreaSize:"ModelingAreaSizeExp"
SET n_MA:(CM VAL n_MAreaSize)

AVAL n_CAreaSize:"CommentAreaSizeExp"
SET n_CA: (CM VAL n_CAreaSize)

AVAL s_CB:"CommentBox"

#--------------Comment Mode YES/NO------------------------------

IF (s_Mode = "Yes") {

PEN color:black
FILL r:220 g:220 b:220
RECTANGLE x:-1.5cm y:0cm w:3cm h:1.5cm

FILL color:lemonchiffon
RECTANGLE x:1.5cm y:-0.5cm w:0.7cm h:0.5cm

SET coli:"darkslategray"
STRETCH off
SHADOW off

#------------------Create Comment Field-----------------------
	IF (s_CB = "Yes") {
	SET x_CA:(n_MA + 1cm)
	FONT h:8pt
	ATTRBOX "Comment" x:abs:(x_CA + 0.2cm) y:(0.3cm) w:(n_CA - 0.4cm) h:1.3cm
	ATTR "Comment" x:abs:(x_CA + 0.2cm) y:(0.3cm) w:(n_CA - 0.4cm) h:1.3cm line-break:rigorous	
	
	ATTR "CommentInfo" format:"%o" x:abs:(x_CA + 0.2cm) y:(0cm) w:(n_CA - 0.4cm) line-break:rigorous
	
	}

#-----------------HOTSPOT's--------------------------------
FONT "Wingdings" h:16pt color:(coli)
TEXT "!" x:1.6cm y:-0.55cm w:0.5cm h:.5cm
HOTSPOT "WriteComment" x:abs:1.5cm y:-0.5cm w:0.7cm h:0.5cm
	text:"Add Comment"
	
	FILL color:lemonchiffon SHADOW on
	RECTANGLE x:2.2cm y:-0.5cm w:0.7cm h:.5cm
	
	PEN w:0.07cm #color:red
	LINE x1:2.4cm y1:-0.1cm x2:2.7cm y2:-0.4cm
	LINE x1:2.7cm y1:-0.1cm x2:2.4cm y2:-0.4cm
	HOTSPOT "ClearComment" x:abs:2.2cm y:-0.5cm w:0.7cm h:0.5cm
		text:"Clear Comment"
}

#-------------------------Non Comment Mode------------------------------
ELSE {
PEN color:black
FILL r:220 g:220 b:220
RECTANGLE x:-1.5cm y:0cm w:3cm h:1.5cm
}