GRAPHREP

  AVAL set-default: "outside" r: "Representation of Name"
  AVAL set-default: "na" s: "State of Satisfaction"
  AVAL i: "Order"

  PEN w:0.05cm color:green endcap:round join:round
  CLIP_ELLIPSE x:0.86cm y:0cm rx:0.3cm ry:0.63cm
  CLIP_ELLIPSE x:-0.86cm y:0cm rx:0.3cm ry:0.63cm combine-mode:or
  GRADIENT_RECT x:-1.2cm y:-.6cm w:2.4cm h:1.3cm style:downdiag color1:white color2:palegreen
  CLIP_OFF
  CLIP_RECT x:-0.7cm y:-.6cm w:1.5cm h:1.6cm
  CLIP_ELLIPSE x:0cm y:-1cm rx:1.1cm ry:0.56cm combine-mode:diff
  CLIP_ELLIPSE x:0cm y:1cm rx:1.1cm ry:0.56cm combine-mode:diff
  GRADIENT_RECT x:-1.2cm y:-.6cm w:2.4cm h:1.3cm style:downdiag color1:white color2:palegreen
  CLIP_OFF 
  CURVE "t" fx:(1.1*sin(t)) fy:(.9+(-0.5*cos(t))+0.05) from:-0.88 to:0.88
  CURVE "t" fx:(1.1*sin(t)) fy:(-.9+.5*cos(t)-0.05) from:-0.88 to:0.88
  #RECTANGLE x:0.83cm y:-0.62cm w:0.3cm h:1.2cm
  # right and left side of "knochen" - line only
  CLIP_RECT x:0.82cm y:-2.5cm w:3cm h:4cm
  ELLIPSE x:0.86cm y:0cm rx:0.3cm ry:0.63cm
  CLIP_OFF
  CLIP_RECT x:-0.82cm y:-2.5cm w:-3cm h:4cm
  ELLIPSE x:-0.86cm y:0cm rx:0.3cm ry:0.63cm
  CLIP_OFF

  
  FONT h:10pt
  AVAL set-default: "10" grad:"Font Size"
  FONT h:(PT grad)

# ADDING WIKI VIEW
  AVAL set-default:"@" wv:"Wiki view"

  IF (r = "inside")
    IF (LEN wv > 1)
      AVAL name:"Name"
      ATTR "Wiki view" text:(name) w:c:2.6cm h:c line-break: words
    ELSE
      ATTR "Name" w:c:2.6cm h:c line-break: words
    ENDIF
  ELSE
    IF (LEN wv > 1)
      AVAL name:"Name"
      ATTR "Wiki view" text:(name) w:c:2.6cm h:t y:0.8cm line-break: words
    ELSE
      ATTR "Name" w:c:2.6cm h:t y:0.8cm line-break: words
    ENDIF   
  ENDIF
# End of WIKI View

    IF (i > "0")
      FONT "Arial" h:10.0pt color:green bold
      ATTR "Order" x:-1.2cm y:0.2cm w:r h:t
    ENDIF

      IF (s = "satisfied")
        PEN w:0.1cm color:green endcap:round join:round
        POLYLINE 3 x1:-1.5cm y1:-0.35cm x2:-1.4cm y2:-0.2cm x3:-1.1cm y3:-0.7cm
      ENDIF

      IF (s = "weakly satisfied")
        PEN w:0.1cm color:green endcap:round join:round
        POLYLINE 3 x1:-1.5cm y1:-0.35cm x2:-1.4cm y2:-0.2cm x3:-1.1cm y3:-0.7cm
        PEN w:0.13cm color:green endcap:round join:round  
        POINT x:-1.25cm y:-0.2cm
      ENDIF

      IF (s = "denied")
        PEN w:0.1cm color:green endcap:round join:round
        POLYLINE 5 x1:-1.51cm y1:-0.6cm x2:-1.52cm y2:-0.6cm x3:-1.42cm y3:-0.35cm x4:-1.32cm y4:-0.2cm x5:-1.28cm y5:-0.25cm
        POLYLINE 2 x1:-1.28cm y1:-0.6cm x2:-1.6cm y2:-0.2cm
      ENDIF

      IF (s = "weakly denied")
        PEN w:0.1cm color:green endcap:round join:round
        POLYLINE 5 x1:-1.51cm y1:-0.6cm x2:-1.52cm y2:-0.6cm x3:-1.42cm y3:-0.35cm x4:-1.32cm y4:-0.2cm x5:-1.28cm y5:-0.25cm
        POLYLINE 2 x1:-1.28cm y1:-0.6cm x2:-1.6cm y2:-0.2cm
        PEN w:0.13cm color:green endcap:round join:round  
        POINT x:-1.46cm y:-0.1cm
      ENDIF

      IF (s = "unknown")
        PEN w:0.1cm color:green endcap:round join:round
        FONT "Times New Roman MT Extra Bold" h:20.0pt color:green
        TEXT "?" x:-1.45cm y:-0.8cm w:l h:t
        PEN w:0.13cm color:green endcap:round join:round  
        POINT x:-1.5cm y:-0.6cm
      ENDIF

      IF (s = "conflict")
        PEN w:0.05cm color:green endcap:square join:miter
        FILL color:green
        POLYGON 6 x1:-1.8cm y1:-0.5cm x2:-1.35cm y2:-0.3cm x3:-1.55cm y3:-0.2cm
                  x4:-1.3cm y4:-0cm x5:-1.75cm y5:-0.2cm x6:-1.55cm y6:-0.3cm
      ENDIF

  AVAL p: "Priority" 

    IF (p > "0")
      PEN 0.08
      FILL color: orange
      ELLIPSE x:1.39cm y:-0.4cm rx:0.23cm ry:0.23cm
      FONT "Arial" h:10.0pt color:black bold
      ATTR "Priority" x:1.39cm y:-0.6cm w:c h:t
    ENDIF