GRAPHREP

AVAL sRepresentation: "Show name"
AVAL sType:           "Type"
AVAL set-default:"1" su:"Sum"
AVAL vis:"display incorrect transition probability"

#-- COLOR DEFINITIONS --
SET colBrd:  (rgbval("$ABAB2A"))
SET colFFm:  (rgbval("white"))
SET colFTo:  (rgbval("$eeee00"))

SHADOW on
PEN w:0.06cm color:(colBrd)
FILL style:null
CLIP_POLY 4 x1:-0.7cm y2:0.7cm x3:0.7cm y4:-0.7cm
GRADIENT_RECT x:-1.3cm y:-1.2cm w:2.8cm h:2.4cm style:downdiag
              color1:(colFFm) color2:(colFTo)
CLIP_OFF
POLYGON 4 x1:-0.7cm y2:0.7cm x3:0.7cm y4:-0.7cm

IF (sType = "Data-based (with marker)")
  #FONT h:24pt bold color:(colBrd)  
  #TEXT "X" x:0cm y:0.05cm w:c h:c
  PEN w:0.2cm color:(colBrd)
  FILL style:null  
  LINE x1:0.2cm y1:0.3cm x2:-0.2cm y2:-.3cm
  LINE x1:0.2cm y1:-0.3cm x2:-0.2cm y2:0.3cm  
ELSIF (sType = "Event-based (instantiate)")
  POLYGON 5
    x1:0cm y1:-0.22cm
    x2:0.18cm y2:-0.03cm
    x3:0.1cm y3:0.16cm
    x4:-0.1cm y4:0.16cm
    x5:-0.18cm y5:-0.03cm
  ELLIPSE rx:0.38cm ry:0.38cm
ELSIF (sType = "Event-based (do not instantiate)")
  POLYGON 5
    x1:0cm y1:-0.22cm
    x2:0.18cm y2:-0.03cm
    x3:0.1cm y3:0.16cm
    x4:-0.1cm y4:0.16cm
    x5:-0.18cm y5:-0.03cm
  ELLIPSE rx:0.38cm ry:0.38cm
  ELLIPSE rx:0.3cm ry:0.3cm
ENDIF

# Visualize "Name"
PEN w:0.06cm color:(colBrd)
FONT #h:9pt
IF (sRepresentation = "center")
  IF (sType = "Data-based (without marker)")   
      ATTR "Name" x:0.0cm y:0.0cm h:c:1.0cm w:c:1.5cm line-break:rigorous
  ENDIF
ELSIF (sRepresentation = "above")  
    ATTR "Name" x:1cm y:-1cm h:b w:l:3cm line-break:words
    ATTRBOX "Name" x:1cm y:-1cm h:b w:l:3cm line-break:words    
  LINE x1:(textx1 - .1cm) y1:(texty1 - .1cm) x2:(textx1 - .1cm) y2:(texty2 + .1cm)
  LINE x1:(textx1 - .1cm) y1:(texty1 - .1cm) x2:(textx1 + .4cm) y2:(texty1 - .1cm)
  LINE x1:(textx1 - .1cm) y1:(texty2 + .1cm) x2:(textx1 + .4cm) y2:(texty2 + .1cm)
  PEN style:dash
  LINE x1:0.35cm y1:-.35cm x2:0.9cm y2:-.9cm
ELSIF (sRepresentation = "below")
    ATTR "Name" x:0.0cm y:0.8cm h:t w:c:3cm line-break:words  
ENDIF

AVAL sOpenQuest:  "Open questions"
IF (LEN sOpenQuest.trim())
  FONT "Arial" h:10.0pt bold color:("red")
  TEXT "?" x:0.50cm y:-0.80cm
ENDIF

IF ((VAL (replall (su, ",", ".")) <> 1) AND
    (vis = "yes"))
  FONT "Arial" h:10.0pt bold color:("red")
  TEXT "!" x:0.8cm y:-.60cm h:c
ENDIF