GRAPHREP
#-- COLOR DEFINITIONS --
SET colBrd:  (rgbval("$62A716"))
SET colFFm:  (rgbval("white"))
SET colFTo:  (rgbval("$99CC33"))

AVAL set-default:"throwing" sTyp: "Type"       #catching, throwing
AVAL sMes: "Message"
AVAL sTim: "Timer"
AVAL sEsc: "Escalation"
AVAL sCom: "Compensation"
AVAL sCon: "Conditional"
AVAL sSig: "Signal"
AVAL sLin: "Link"
AVAL sPar: "Parallel"
AVAL showName:"Show name"  
AVAL set-default:"classbar" change_mark:"Object type" #ZMI - trick to get proper classbar visualisation
 


SET bErrorMarker: 1

CLIP_ELLIPSE rx:.7cm ry:.7cm
GRADIENT_RECT x:-0.9cm y:-.7cm w:2.8cm h:1.4cm style:downdiag
             color1:(colFFm) color2:(colFTo)
CLIP_OFF
SHADOW off

PEN w:0.055cm color:(colBrd)
ELLIPSE rx:.7cm ry:.7cm
PEN w:0.04cm color:(colBrd)
ELLIPSE rx:.6cm ry:.6cm

PEN w:0.055cm color:(colBrd)
# check for multiple triggers
IF (((sTyp = "catching") AND
         (((sMes = "Yes") AND ((sTim = "Yes") OR (sCon = "Yes") OR (sSig = "Yes") OR (sLin = "Yes"))) OR
          ((sTim = "Yes") AND ((sMes = "Yes") OR (sCon = "Yes") OR (sSig = "Yes") OR (sLin = "Yes"))) OR
          ((sCon = "Yes") AND ((sTim = "Yes") OR (sMes = "Yes") OR (sSig = "Yes") OR (sLin = "Yes"))) OR
          ((sSig = "Yes") AND ((sTim = "Yes") OR (sCon = "Yes") OR (sMes = "Yes") OR (sLin = "Yes"))))
    ) OR
    ((sTyp = "throwing") AND          
         (((sMes = "Yes") AND ((sEsc = "Yes") OR (sCom = "Yes") OR (sSig = "Yes") OR (sLin = "Yes"))) OR
          ((sEsc = "Yes") AND ((sMes = "Yes") OR (sCom = "Yes") OR (sSig = "Yes") OR (sLin = "Yes"))) OR
          ((sCom = "Yes") AND ((sEsc = "Yes") OR (sMes = "Yes") OR (sSig = "Yes") OR (sLin = "Yes"))) OR
          ((sSig = "Yes") AND ((sEsc = "Yes") OR (sCom = "Yes") OR (sMes = "Yes") OR (sLin = "Yes"))))          
    ))
  IF (sPar = "Yes")
    IF (sTyp = "catching")
      POLYGON 12
        x1:-0.1cm y1:-0.1cm
        x2:-0.1cm y2:-0.4cm
        x3:0.1cm y3:-0.4cm
        x4:0.1cm y4:-0.1cm
        x5:0.4cm y5:-0.1cm
        x6:0.4cm y6:0.1cm
        x7:0.1cm y7:0.1cm
        x8:0.1cm y8:0.4cm
        x9:-0.1cm y9:0.4cm
        x10:-0.1cm y10:0.1cm
        x11:-0.4cm y11:0.1cm
        x12:-0.4cm y12:-0.1cm
    ELSE
      FILL color:(colBrd)
      POLYGON 5
        x1:0.0cm y1:-0.45cm
        x2:0.45cm y2:-0.1cm
        x3:0.3cm y3:0.4cm
        x4:-0.3cm y4:0.4cm
        x5:-0.45cm y5:-0.1cm      
    ENDIF
    SET bErrorMarker: 0  
  ELSE
    IF (sTyp = "throwing")
      FILL color:(colBrd)
    ENDIF
    POLYGON 5
      x1:0.0cm y1:-0.45cm
      x2:0.45cm y2:-0.1cm
      x3:0.3cm y3:0.4cm
      x4:-0.3cm y4:0.4cm
      x5:-0.45cm y5:-0.1cm   
    SET bErrorMarker: 0      
  ENDIF
ELSE
  IF (sMes = "Yes")    
    IF (sTyp = "catching")
      RECTANGLE x:-.4cm y:-.3cm w:.8cm h:.6cm
      POLYLINE 3 x1:-.4cm y1:-.3cm x2:.0cm y2:.0cm x3:.4cm y3:-.3cm    
    ELSE
      PEN w:0.06cm color:(colBrd)
      FILL color:(colBrd)
      RECTANGLE x:-.4cm y:-.3cm w:.8cm h:.6cm
      PEN color:white w:1pt
      POLYLINE 3 x1:-.4cm y1:-.3cm x2:.0cm y2:.0cm x3:.4cm y3:-.3cm
      PEN w:0.055cm color:(colBrd)
    ENDIF
    SET bErrorMarker: 0
  ELSIF (sTim = "Yes")
    IF (sTyp = "catching")  
      TABLE  x:-0.4cm y:-0.4cm w:0.8cm h:0.8cm cols:4 rows:4
             w1:0.16cm w2:0.24cm w3:0.24cm w4:0.16cm
             h1:0.16cm h2:0.24cm h3:0.24cm h4:0.16cm   

      LINE x1:(tabx1) y1:(taby0) x2:(tabx3) y2:(taby4)
      LINE x1:(tabx2) y1:(taby0) x2:(tabx2) y2:(taby4)
      LINE x1:(tabx3) y1:(taby0) x2:(tabx1) y2:(taby4)
      LINE x1:(tabx0) y1:(taby1) x2:(tabx4) y2:(taby3)
      LINE x1:(tabx0) y1:(taby2) x2:(tabx4) y2:(taby2)
      LINE x1:(tabx0) y1:(taby3) x2:(tabx4) y2:(taby1)

      CLIP_ELLIPSE rx:0.5cm ry:0.5cm
      CLIP_ELLIPSE rx:0.4cm ry:0.4cm combine-mode:xor
      GRADIENT_RECT x:-0.9cm y:-.7cm w:2.8cm h:1.4cm style:downdiag
                   color1:(colFFm) color2:(colFTo)
      CLIP_OFF
      ELLIPSE rx:.4cm ry:.4cm
      CLIP_ELLIPSE rx:.25cm ry:.25cm
      GRADIENT_RECT x:-0.9cm y:-.7cm w:2.8cm h:1.4cm style:downdiag
               color1:(colFFm) color2:(colFTo)
      CLIP_OFF
      PEN w:0.05cm color:(colBrd)
      LINE x1:0.0cm y1:0.0cm x2:0.065cm y2:-0.3cm
      LINE x1:0.0cm y1:0.0cm x2:0.20cm y2:0.0cm
      FILL color:(colBrd)
      ELLIPSE rx:.04cm ry:.04cm
      SET bErrorMarker: 0
    ELSIF (sTyp = "throwing")
      SET bErrorMarker: 0      
    ENDIF
  ELSIF (sCon = "Yes")
    IF (sTyp = "catching")
      RECTANGLE x:-.35cm y:-.35cm w:.7cm h:.7cm
      PEN w:0.05cm color:(colBrd)
      LINE x1:-0.25cm y1:-0.2cm x2:0.25cm y2:-0.2cm
      LINE x1:-0.25cm y1:0.2cm x2:0.25cm y2:0.2cm
      LINE x1:-0.25cm y1:0.07cm x2:0.25cm y2:0.07cm
      LINE x1:-0.25cm y1:-0.07cm x2:0.25cm y2:-0.07cm
      SET bErrorMarker: 0      
    ELSIF (sTyp = "throwing")
      SET bErrorMarker: 0      
    ENDIF
  ELSIF (sSig = "Yes")
    IF (sTyp = "throwing")
      FILL color:(colBrd)
    ENDIF
    POLYGON 3
      x1:0.0cm y1:-0.45cm
      x2:0.4cm y2:0.3cm
      x3:-0.4cm y3:0.3cm
    SET bErrorMarker: 0      
  ELSIF (sLin = "Yes")
    IF (sTyp = "throwing")
      FILL color:(colBrd)
    ENDIF    
    PEN w:0.06cm color:(colBrd)
    POLYGON 7
      x1:-0.35cm y1:-0.1cm
      x2:0.15cm y2:-0.1cm
      x3:0.15cm y3:-0.2cm
      x4:0.45cm y4:0.0cm
      x5:0.15cm y5:0.2cm
      x6:0.15cm y6:0.1cm
      x7:-0.35cm y7:0.1cm
    SET bErrorMarker: 0    
  ELSIF (sEsc = "Yes")
    IF (sTyp = "throwing")    
      FILL color:(colBrd)
      POLYGON 4
        x1:0.0cm y1:-0.40cm
        x2:0.28cm y2:0.25cm
        x3:0cm y3:-0.025cm
        x4:-0.28cm y4:0.25cm
      SET bErrorMarker: 0
    ENDIF
  ELSIF (sCom = "Yes")
    IF (sTyp = "throwing")
      FILL color:(colBrd)
      POLYGON 3
        x1:0.0cm y1:-0.2cm
        x2:0.0cm y2:0.2cm
        x3:-0.32cm y3:0.0cm
      POLYGON 3
        x1:0.32cm y1:-0.2cm
        x2:0.32cm y2:0.2cm
        x3:0.0cm y3:0.0cm      
      SET bErrorMarker: 0
    ENDIF
  ELSE
    IF (sTyp = "throwing")
      SET bErrorMarker: 0
    ENDIF    
  ENDIF
ENDIF  

IF (bErrorMarker = 1)
  FONT "Arial" h:16pt color:red bold
  TEXT "!" x:0cm y:0cm w:c h:c    
ENDIF

IF (showName = "Yes")
  FONT
    ATTR "Name" x:0.0cm y:0.8cm w:c:2.0cm h:t line-break:words
ENDIF

AVAL sOpenQuest:  "Open questions"
IF (LEN sOpenQuest.trim())
  FONT "Arial" h:10.0pt bold color:("red")
  TEXT "?" x:0.60cm y:-0.80cm
ENDIF
# inserted for visualization in classbar
IF (change_mark = "classbar")
{
  RECTANGLE x:-.4cm y:-.3cm w:.8cm h:.6cm
  POLYLINE 3 x1:-.4cm y1:-.3cm x2:.0cm y2:.0cm x3:.4cm y3:-.3cm
}