GRAPHREP sizing:asymmetrical
SHADOW off
PEN w:0.02cm
AVAL t:"Type"
AVAL fc:"Font color"

AVAL set-default:"$ffffff" c:"Color"
FILL color:(rgbval (c))

FONT h:12.0pt bold color:(fc)

TABLE x:0.0cm y:0.0cm w:8.0cm h:4.0cm cols:4 rows:4
        w1:0.2cm w2:70% w3:30% w4:0.2cm
        h1:0.2cm h2:50% h3:50% h4:0.2cm

IF (t="Interaction Reference")
  RECTANGLE x:0.0cm y:0.0cm w:c:8cm h:c:4cm
  STRETCH off
  PEN color:(fc)
  POLYGON 5
  x1:0.0cm y1:0.0cm
  x2:0.0cm y2:0.5cm
  x3:(tabx2) y3:0.5cm
  x4:(tabx2+0.2cm) y4:0.4cm
  x5:(tabx2+0.2cm) y5:0.0cm
  FILL
  STRETCH on
ELSE
  RECTANGLE x:0.0cm y:0.0cm w:c:8cm h:c:4cm
  AVAL set-default:"$ffffff" c:"Color"
  FILL color:(rgbval (c))
  STRETCH off
  PEN color:(fc)
  POLYGON 5
  x1:0.0cm y1:0.0cm
  x2:0.0cm y2:0.5cm
  x3:(tabx2) y3:0.5cm
  x4:(tabx2+0.2cm) y4:0.4cm
  x5:(tabx2+0.2cm) y5:0.0cm
  FILL
  STRETCH on
ENDIF

IF (t="Interaction Reference")
  STRETCH off
  TEXT "ref" x:0.3cm y:0.0cm w:2.00cm h:t

  AVAL set-format:"%o" io:"Interaction (Object)"
  AVAL set-format:"%m" im:"Interaction (Model)"
  SET at:("")
  AVAL a:"Attribute"
  IF (LEN a) SET at:(a + "=") ENDIF
  SET inpara:("")
  SET outpara:("")
  SET rw:("")
  AVAL inp:"Inputparameter"
  AVAL outp:"Output parameter"
  AVAL rgw:"Return value"
  IF (LEN inp) SET inpara:(inp) ENDIF
  IF (LEN outp) SET outpara:("out " + outp) ENDIF
  IF ((LEN inp) AND (LEN outp)) SET inpara:(inpara + " ") ENDIF
  IF (LEN rgw) SET rw:(":" + rgw) ENDIF

  IF (LEN io)
    FONT h:12.0pt color:(fc)

    ATTR "Interaction (Object)" text:(at + io + "(" + inpara + outpara + ")" + rw) format:"%o" x:(tabx1+0.2cm) y:(taby1+0.5cm) w:l:(tabx3-tabx1-0.2cm) h:t:(taby3-taby1-0.2cm) line-break:rigorous
    FONT color:(fc)
  ELSIF (LEN im)
    FONT h:12.0pt color:(fc)
    ATTR "Interaction (Model)" text:(at + im + "(" + inpara + outpara + ")" + rw) format:"%m" x:(tabx1+0.2cm) y:(taby1+0.5cm) w:l:(tabx3-tabx1-0.2cm) h:t:(taby3-taby1-0.2cm) line-break:rigorous
    FONT color:(fc)
  ENDIF
STRETCH on
ELSIF (t="Alternative")

  AVAL a1:"Alternative A"
  AVAL a2:"Alternative B"

  FONT h:12.0pt bold color:(fc)
  STRETCH off
  TEXT "alt" x:0.3cm y:0.0cm w:2.00cm h:t

  PEN style:dash color:(fc)
  LINE x1:(tabx0) y1:(taby2) x2:(tabx3+0.2cm) y2:(taby2)
  STRETCH on
  FONT h:10.0pt color:(fc)
  IF (LEN a1)
    STRETCH off
    ATTR "Alternative A" text:("[" + a1 + "]") x:(tabx1+0.2cm) y:(taby1+0.6cm) w:l:(tabx3-tabx1-0.2cm) h:t:0.1cm line-break:rigorous
    STRETCH on
  ENDIF
  IF (LEN a2)
    STRETCH off
    ATTR "Alternative B" text:("[" + a2 + "]") x:(tabx1+0.2cm) y:(taby2+0.2cm) w:l:(tabx3-tabx1-0.2cm) h:t:0.1cm line-break:rigorous
    STRETCH on
  ENDIF
  FONT
ELSIF (t="Option")

  AVAL op:"Option parameter"
  FONT h:12.0pt bold color:(fc)
  STRETCH off
  TEXT "opt" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
  FONT h:12.0pt color:(fc)
  IF (LEN op)
    STRETCH off
    ATTR "Option parameter" text:("[" + op + "]") x:(tabx1+0.2cm) y:(taby1+0.6cm) w:l:(tabx3-tabx1-0.2cm) h:t:0.1cm line-break:rigorous
    STRETCH on
  ENDIF
FONT


ELSIF (t="Break")
  STRETCH off
  TEXT "break" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
ELSIF (t="Parallel")
  STRETCH off
  TEXT "par" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
  AVAL anzb:"Parallel paths"

  PEN style:dash color:(fc)
  IF (anzb = "1")
  ELSIF (anzb = "2")
    LINE x1:0.0cm y1:2.0cm x2:8.0cm y2:2.0cm
  ELSIF (anzb = "3")
    LINE x1:0.0cm y1:1.333cm x2:8.0cm y2:1.333cm
    LINE x1:0.0cm y1:2.666cm x2:8.0cm y2:2.666cm
  ELSIF (anzb = "4")
    LINE x1:0.0cm y1:1.0cm x2:8.0cm y2:1.0cm
    LINE x1:0.0cm y1:2.0cm x2:8.0cm y2:2.0cm
    LINE x1:0.0cm y1:3.0cm x2:8.0cm y2:3.0cm
  ENDIF

ELSIF (t="Weak Sequencing")
  STRETCH off
  TEXT "seq" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
ELSIF (t="Strict Sequencing")
  STRETCH off
  TEXT "strict" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
ELSIF (t="Negative")
  STRETCH off
  TEXT "neg" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
ELSIF (t="Critical Region")
  STRETCH off
  TEXT "critical" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
ELSIF (t="Ignore")
  FONT h:12.0pt bold color:(fc)
  AVAL ipara: "Ignore Parameter"

  SET iparam:("")
  IF (LEN ipara) SET iparam:("{" + ipara + "}") ENDIF
  STRETCH off
  ATTR "Type" text:("ignore" + iparam) x:0.3cm y:0.0cm w:l:(tabx2-tabx1) h:t:0.1cm line-break:rigorous
  STRETCH on
ELSIF (t="Consider")

  FONT h:12.0pt bold color:(fc)
  AVAL cpara: "Consider Parameter"

  SET cparam:("")
  IF (LEN cpara) SET cparam:("{" + cpara + "}") ENDIF
  STRETCH off
  ATTR "Type" text:("consider" + cparam) x:0.3cm y:0.0cm w:l:(tabx2-tabx1) h:t:0.1cm line-break:rigorous
  STRETCH on
ELSIF (t="Assertion")
  STRETCH off
  TEXT "assert" x:0.3cm y:0.0cm w:2.00cm h:t
  STRETCH on
ELSIF (t="Loop")
  FONT h:12.0pt bold color:(fc)

  AVAL mini: "Minimum number of Iterations"
  AVAL maxi: "Maximum number of Iterations"

  SET rng:("")
  IF ((LEN mini) AND (LEN maxi) AND (maxi > "0"))
    SET rng:("(" + mini + "," + maxi + ")")
  ENDIF
  STRETCH off
  ATTR "Type" text:("loop" + rng) x:0.3cm y:0.0cm w:l:(tabx2-tabx1) h:t:0.1cm line-break:rigorous
  STRETCH on
ENDIF